崔济东的博客 – JiDong Cui's Blog

ANSYS 影响线分析。(Influence line analysis using ANSYS)

• 算例（Example）

• ANSYS有限元模拟（FEM Analysis with ANSYS）

命令流：

FINISH
/CLEAR
/TITLE,Influence Line Analysis
/PREP7

!Element type
ET,1,BEAM3

!Material
MP,EX,1,25000
MP,PRXY,1,0.2

!Real for beam 200X500
!R,NO,AREA,IZZ,TKZ,SHEARZ
R,1,100000,2.083E+09,500,0

!Node
NMAX=41
DX=300

*DO,I,1,NMAX
N,I,(I-1)*DX,0,0
*ENDDO

!Beam element
REAL,1

*DO,I,1,(NMAX-1)
EN,I,I,I+1
*ENDDO

!Displacement boundary conditions
D,1,UY,0
D,1,UZ,0
D,1,ROTX,0
D,1,ROTY,0

D,11,UX,0
D,11,UY,0
D,11,UZ,0
D,11,ROTX,0
D,11,ROTY,0

D,31,UY,0
D,31,UZ,0
D,31,ROTX,0
D,31,ROTY,0

D,41,UY,0
D,41,UZ,0
D,41,ROTX,0
D,41,ROTY,0

FINISH

/SOLU
ALLSEL,ALL
ANTYPE,STATIC
*Do,I,1,NMAX
TIME,I
!delete force load on nodes
FDELE,ALL,ALL
F,I,FY,-1
SOLVE
*ENDDO

FINISH
/POST26
!node displacement
NSOL,2,20,U,Y
PLVAR,2
!element moment
ESOL,3,20,21,M,Z
PLVAR,3
!element shear force
ESOL,4,20,21,F,Y
PLVAR,4

输入以上命令流，运行分析，即可获得分析结果。

• 查看分析结果（Check Results）

Influence line of displacement:

Influence line of moment:

Influence line of shear force:

• 与SAP2000分析结果对比（Comparison with SAP2000 results ）

Influence line of displacement:

Influence line of moment:

Influence line of shear force:

• 注释 ( Comments )

(大家一起学习有限元!!!! 如有错漏，欢迎批评指正。Email : jidong_cui@163.com)

( If  you have found any problem about this post, please don’t hesitate to contact me directly.  Email : jidong_cui@163.com)

• 相关博文( Related Posts)

[01]. Torsion analysis by thermal analogy with ANSYS (ANSYS热比拟扭转应力分析)

[02]. Analysis of a Euler–Bernoulli beam with ANSYS [ANSYS 欧拉-伯努利梁分析]

[03]. Modal analysis of a frame using ANSYS (ANSYS框架模态分析)

[04]. Array parameters in ANSYS (ANSYS中的数组参数)

[05]. TABLE type array parameters in ANSYS (ANSYS中的表格型数组参数)

• ANSYS中的数组参数（Array parameters in ANSYS）

ANSYS中的数组参数是APDL语言中十分重要的参数，在定义材料参数、施加荷载及定义分析工况等时候都会用到数组来储存数据。

ANSYS中的Array参数包括三种类型：数组（ARRAY），字符串(CHAR)，表格(TABLE)。

表格(TABLE)类型的数组参数与数组（ARRAY）类型的数组参数十分相似。前一个博文《Array parameters in ANSYS (ANSYS中的数组参数)》介绍了数组（ARRAY）类型的数组参数，与数组（ARRAY）类型的数组相比，表格(TABLE)类型的数组参数具有以下的一些不同点：TABLE的的值通过线性插值来访问，TABLE包括0行和0列作为TABLE数值的索引，0行0列的值可以是实数。

以下通过几个命令流来学习表格(TABLE)类型的数组参数。

• ANSYS中的表格型数组参数（TABLE type array parameters in ANSYS）

（1）4x2x2的TABLE定义（Definition of TABLE）

FINISH
/CLEAR
/TITLE,array parameters of ANSYS
/PREP7

*DIM,E,TABLE,4,2,2,Time,Acc,Type
E(0,0,1)=100
E(0,0,2)=200

E(1,0,1)=0,0.4,0.5,0.6
E(0,1,1)=0,2,4,6,8
E(0,2,1)=1,3,5,7,9

E(1,0,2)=0,0.1,0.2,0.3
E(0,1,2)=1,11,12,13,14
E(0,2,2)=2,16,17,18,19

（2）TABLE的访问（Access of TABLE）

E00=E(0,0,100) !2
E01=E(0,0,200) !11

E00100=E(0,0,100) !2
E01100=E(0,1,100) !3

E00200=E(0,0,200) !11
E01200=E(0,1,200) !16

E01200=E(0,1,200) !16
E012=E(0,1,2) !3

E001=E(0,0,1) !2
E011=E(0,1,1) !3

E020100=E(0.2,0,100) !3
E005100=E(0,0.5,100) !2.5

E020200=E(0.2,0,200) !11.5=(11+12)/2 = 11.5
E005200=E(0,0.5,200) !(11+16)/2 = 13.5

E0201=E(0.2,0,1) !3=(2+4)/2
E0051=E(0,0.5,1) !2.5=(2+3)/2

E0701=E(0.7,0,1) !8
E07051=E(0.7,0.5,1) !8.5=(8+9)/2;

E021001=E(0.2,100,1) !4=(3+5)

E01150=E(0,1,150) !9.5=(3+16)/2
E005150=E(0,0.5,150) !8=(2.5+(11+16)/2)/2

E01180=E(0,1,180) !13.4=(3*0.2+16*0.8)
E005180=E(0,0.5,180) !11.3=(2.5*0.2+(16+11)/2*0.8)

（3）结论（Conclusions）

从以上的测试可以发现：

a. TABLE表格赋值的时候和ARRAY类型的数组参数类似，都是按列来赋值。

b. TABLE之间的值通过插值的形式来访问，另外当存在多个平面（Plane）的时候，以第一个平面的0行和0列的值作为插值索引的基础。

c. TABLE访问的时候不能外插，当值在超过索引范围的时候，取最外围的值。

• 相关博文( Related Posts)

[01]. Torsion analysis by thermal analogy with ANSYS (ANSYS热比拟扭转应力分析)

[02]. Analysis of a Euler–Bernoulli beam with ANSYS [ANSYS 欧拉-伯努利梁分析]

[03]. Modal analysis of a frame using ANSYS (ANSYS框架模态分析)

[04]. Array parameters in ANSYS (ANSYS中的数组参数)

• ANSYS中的数组参数（Array parameters in ANSYS）

ANSYS中的数组参数是APDL语言中十分重要的参数，在定义材料参数、施加荷载及定义分析工况等时候都会用到数组来储存数据。

ANSYS中的Array参数包括三种类型：数组（ARRAY），字符串(CHAR)，表格(TABLE)。

Array参数又可以从维度上分为 (ANSYS arrays can be)：

一维（列）：One-dimensional (a single column)
一维（行,列）：Two-dimensional (rows and columns)
三维（行,列,平面）：Three-dimensional (rows, columns, and planes)

以下通过几个命令流来学习数组（ARRAY）类型的数组参数。

• ANSYS中的ARRAY型数组参数（ARRAY type array parameters in ANSYS）

（1）定义一个2X4列的数组，并给每一列数组赋值

*DIM,A,ARRAY,2,4
A(1,1)=1,2
A(1,2)=3,4
A(1,3)=5,6
A(1,4)=7,8

（2）定义一个4X1的数组，并赋值

*DIM,B,ARRAY,4,1
B(1,1)=1,2,3,4

（3）定义一个2X3X2的数组，并赋值

*DIM,D,ARRAY,2,3,2
D(2,1,1)=1
D(1,2,1)=3,4
D(1,3,1)=5,6
D(1,1,2)=7,8
D(1,2,2)=9,10
D(1,3,2)=11,12

（4）数组的访问

A11=A(1,1)
A24=A(2,4)

D111 = D(1,1,1)
D211 = D(2,1,1)
D221 = D(2,2,1)

从以上例子可见，ANSYS中的ARRAY数组是按列来赋值的。

• 相关博文( Related Posts)

[01]. Torsion analysis by thermal analogy with ANSYS (ANSYS热比拟扭转应力分析)

[02]. Analysis of a Euler–Bernoulli beam with ANSYS [ANSYS 欧拉-伯努利梁分析]

[03]. Modal analysis of a frame using ANSYS (ANSYS框架模态分析)

ANSYS 框架结构模态分析练习。(This is a small example to outline the steps required to do a simple modal analysis of a frame structure using ANSYS.)

• 算例（Example）

• ANSYS有限元模拟（FEM Analysis with ANSYS）

这个问题可以很简单的通过命令流的方式进行建模，如下给出具体的命令流：

FINISH
/CLEAR
/TITLE,Modal analysis of a frame
/PREP7

!Element type
ET,1,BEAM4

!Material
MP,EX,1,32500
MP,PRXY,1,0.2
MP,DENS,1,2.403E-09

!Real for beam 200X500
!R,NO,AREA,IZZ,IYY,TKZ,TKY,THETA
R,1,100000,3.333E+08,2.083E+09,500,200,
!ISTRAIN,IXX,SHEARZ,SHEARY
RMORE,0,9.981E+08,0,0

!Real for Column 600X600
!R,NO,AREA,IZZ,IYY,TKZ,TKY,THETA
R,2,360000,1.080E+10,1.080E+10,600,600,
!ISTRAIN,IXX,SHEARZ,SHEARY
RMORE,0,1.825E+10,0,0

!Nodes
N,1,-3000,-3000,0
N,2,-3000,-3000,3000
N,3,-3000,-3000,6000
N,4,-3000,-3000,9000
N,5,-3000,3000,0
N,6,-3000,3000,3000
N,7,-3000,3000,6000
N,8,-3000,3000,9000
N,9,3000,-3000,0
N,10,3000,-3000,3000
N,11,3000,-3000,6000
N,12,3000,-3000,9000
N,13,3000,3000,0
N,14,3000,3000,3000
N,15,3000,3000,6000
N,16,3000,3000,9000

!Direction Nodes
N,41,-3000,-3000,12000
N,161,3000,3000,12000
N,91,6000,-3000,0
N,131,6000,3000,0

!Column elements
REAL,2
EN,1,1,2,91
EN,2,2,3,91
EN,3,3,4,91
EN,4,5,6,131
EN,5,6,7,131
EN,6,7,8,131
EN,7,9,10,91
EN,8,10,11,91
EN,9,11,12,91
EN,10,13,14,131
EN,11,14,15,131
EN,12,15,16,131

!Beam elements
REAL,1
EN,13,2,10,41
EN,14,3,11,41
EN,15,4,12,41
EN,16,6,14,161
EN,17,7,15,161
EN,18,8,16,161
EN,19,2,6,41
EN,20,3,7,41
EN,21,4,8,41
EN,22,10,14,161
EN,23,11,15,161
EN,24,12,16,161

!Displacement boundary conditions
D,1,UX,0
D,1,UY,0
D,1,UZ,0
D,1,ROTX,0
D,1,ROTY,0
D,1,ROTZ,0

D,5,UX,0
D,5,UY,0
D,5,UZ,0
D,5,ROTX,0
D,5,ROTY,0
D,5,ROTZ,0

D,9,UX,0
D,9,UY,0
D,9,UZ,0
D,9,ROTX,0
D,9,ROTY,0
D,9,ROTZ,0

D,13,UX,0
D,13,UY,0
D,13,UZ,0
D,13,ROTX,0
D,13,ROTY,0
D,13,ROTZ,0

FINISH

!Analysis options
/SOLU
ANTYPE,2
MODOPT,LANB,12,,,,1
MXPAND,12,,,YES
LUMPM,ON

!Solve
SOLVE
FINISH

!Post process
/POST1
SET,LIST
SET,1,1
PLDISP,1

输入以上命令流，运行分析，即可获得分析结果。

• 查看分析结果（Check Results）

• 与SAP2000分析结果对比（Comparison with SAP2000 results ）

SAP2000中建立欧拉梁单元模型，参见博文 ：《Modal analysis of a frame using Abaqus (Abaqus框架模态分析)》

SAP2000分析结果：

从以上对比可见，SAP2000的分析结果与ANSYS的分析结果一致。

• 相关博文( Related Posts)

[01]. Torsion analysis by thermal analogy with ANSYS (ANSYS热比拟扭转应力分析)

[02]. Analysis of a Euler–Bernoulli beam with ANSYS [ANSYS 欧拉-伯努利梁分析]

稳态热传导的控制方程与经典扭转理论的控制方程具有相似性。我们可以通过比拟，在通用有限元软件中利用稳态热传导分析的功能进行扭转问题的分析。本文结合ANSYS软件，通过一个实例说明这个比拟的具体过程。(The steady heat conduction problem and the classic torsion theory have analogy in their control partial differential equations. We can conduct a torsional analysis making use of the steady analysis fuction in general finite element program. This post gives an example on how to do torsion analysis as thermal analogy with ANSYS.)

• 稳态热传导控制方程与扭转控制方程 （ Control partial differential equations of steady heat conduction problem and classic torsion theory）

（1）稳态热传导控制方程

2D情况下的稳态热传导控制方程

（2）St. Venant 扭转偏微分方程

两者的偏微分方程均为Helmholtz方程的特殊形式。因此可以利用通用有限元软件中的稳态热传导分析功能通过比拟进行截面的扭转应力分析。

• 算例（Example）

• 有限元模拟（FEM Analysis）

 利用ANSYS APDL进行分析，具体步骤如下：

（1）在前处理模块中新建单元类型（Create Element Type in Preprocessor Module）

采用77号单元

（2）在前处理模块中新建材料（Create Material in Preprocessor Module）

材料主要定义热传导系数

（3）在前处理模块创建面并划分网格（Create Area and Mesh in Preprocessor Module）

（4）施加零温度边界条件（Apply Zero Temperature Boundary Condition）

（5）施加热源（Apply Heat on Area）

等效热源：2Gθ = 2*76923*0.0005 = 76.923

（6）求解有限元模型（Solve FEM model in Solution Module）

进行稳态热传导分析

（7）查看结果（Check Results）

• 查看分析结果（Results）

（1）查看节点温度 (Nodal Temperature)

可以看出扭转应力函数的形状。

（2）查看温度梯度 (Nodal Temperature Gradient)

（3）查看热流量向量 (Thermal Flux Vector)

从热流量向量图也可以看出，矩形截面扭转剪切应力的分布：边的中间最大，角点为0。

•  与理论结果对比（Comparison with Theory ）

根据弹性理论，θ = T/ (ab³Gβ₁) , τ_max = T/ (ab²β).

τ_max = θ(ab³Gβ₁) / (ab²β) = θbGβ₁ / β = 0.0005*20*76923*0.141/0.208 = 521.4492Mpa

与分析结果 519.165Mpa相近。

欧拉伯-努利梁理论（Euler–Bernoulli beam）又称为工程梁理论（Engineering beam theory）或者经典梁理论（Classical beam theory）。欧拉梁不考虑剪切变形，与铁木辛柯梁（Timoshenko beam）相对。前面一篇博文《Analysis of a Euler–Bernoulli beam with Abaqus [Abaqus欧拉-伯努利梁分析]》复习了Abaqus中利用欧拉梁单元B23和B33单元进行悬臂梁的模拟，本文接着看看在 ANSYS APDL 中如何利用欧拉梁单元进行同样的分析。

• 算例（Example）

• 有限元模拟（FEM Analysis）

 整个悬臂梁在ANSYS APDL中的分析步骤如下：

（1）在前处理模块中新建单元类型（Create Element Type in Preprocessor Module）

ANSYS中欧拉梁单元可以用BEAM3和 BEAM4单元来考虑，由于高版本的 ANSYS APDL （貌似是13版本开始） 不再支持GUI方式进行BEAM3和BEAM4单元的建模，高版本的ANSYS GUI 主要支持功能强大的 BEAM 188 和 BEAM189 单元。要建立BEAM3和BEAM4单元，可以通过命令流的方式。输入命令：ET,1,BEAM3  ，完成单元类型的建立：

（2）在前处理模块中新建线弹性材料（Create Elastic Material in Preprocessor Module）

（3）在前处理模块中定义单元的实常数（Create Real Constants for Element in Preprocessor Module）

同样，高版本的ANSYS APDL也不支持GUI方式建立BEAM3和BEAM4单元的实常数，只能通过命令来定义。

输入命令：R, 1, 7960, 173450333.333333，350，0  ，完成实常数的建立:

其中 7960 为截面的面积；1734503333.333333 为截面的惯性矩； 350为截面的高度，0表示不考虑剪切效应，单元退化为欧拉梁单元。

（4）在前处理模块创建节点和单元（Create Node and Element for Element in Preprocessor Module）

由于模型节点，直接建立节点（Nodes）和单元（Elements)。基本路径是 Preprocessor->Create-> Nodes 和 Preprocessor->Create->Elements。

（5）在前处理模块创建约束和节点力（Create Nodal Load and Constraint in Preprocessor Module）

施加点力和约束。基本路径是 Preprocessor->Loads-> Apply->Structural->Disp和 Preprocessor->Loads-> Apply->Structural->Force。

（5）求解有限元模型（Solve FEM model in Solution Module）

（6）查看结果（Check Results）

• 查看分析结果（Results）

（1）变形结果（Displacement Results）

最大的竖向位移为 12.0111 mm。

（2） 截面应力结果（Section Stress Results）

截面应力的查看需要通过定义 单元表 （Element Table）来查看。

截面的最大应力为 50.4467Mpa。

（3）支座反力（Reaction Force）

•  与理论结果对比（Comparison with Theory ）

（1）位移对比（Comparison of displacement ）

端部位移的理论值 : U2 = F*L³/3EI = 10000*5000³/(3*200000*173450333.333333) = 12.0111 mm.

ANSYS的分析结果为12.011mm，等于理论结果。

（2）截面应力对比（Comparison of section stress）

端部截面的最大应力为：σ = My/I = 10000*50000*175 / (173450333.333333 ) = 50.4467 Mpa

ANSYS的分析结果为50.447Mpa，等于理论结果。